Update

lib/nulla_web/controllers/actor_controller.ex

@@ -0,0 +1,43 @@
+defmodule NullaWeb.ActorController do
+  use NullaWeb, :controller
+  alias Nulla.ActivityPub
+  alias Nulla.Utils
+  alias Nulla.Models.Actor
+  alias Nulla.Models.Note
+  alias Nulla.Models.InstanceSettings
+
+  def show(conn, %{"username" => username}) do
+    accept = List.first(get_req_header(conn, "accept"))
+    instance_settings = InstanceSettings.get_instance_settings!()
+    domain = instance_settings.domain
+
+    case Actor.get_actor(username, domain) do
+      nil ->
+        conn
+        |> put_status(:not_found)
+        |> json(%{error: "Not Found"})
+
+      %Actor{} = actor ->
+        if accept in ["application/activity+json", "application/ld+json"] do
+          conn
+          |> put_resp_content_type("application/activity+json")
+          |> send_resp(200, Jason.encode!(ActivityPub.actor(actor)))
+        else
+          notes = Note.get_latest_notes(actor.id)
+          following = Utils.count_following_by_username!(actor.preferredUsername)
+          followers = Utils.count_followers_by_username!(actor.preferredUsername)
+
+          render(
+            conn,
+            :show,
+            domain: domain,
+            actor: actor,
+            notes: notes,
+            following: following,
+            followers: followers,
+            layout: false
+          )
+        end
+    end
+  end
+end