defmodule NullaWeb.ActorController do
  use NullaWeb, :controller
  alias Nulla.ActivityPub
  alias Nulla.Models.Actor
  alias Nulla.Models.Relation
  alias Nulla.Models.Note
  alias Nulla.Models.InstanceSettings

  def show(conn, %{"username" => username}) do
    format = Phoenix.Controller.get_format(conn)
    instance_settings = InstanceSettings.get_instance_settings!()
    domain = instance_settings.domain

    case Actor.get_actor(preferredUsername: username, domain: domain) do
      nil ->
        conn
        |> put_status(:not_found)
        |> json(%{error: "Not Found"})

      %Actor{} = actor ->
        if format == "activity+json" do
          conn
          |> put_resp_content_type("application/activity+json")
          |> send_resp(200, Jason.encode!(ActivityPub.actor(actor)))
        else
          following = Relation.count_following(actor.id)
          followers = Relation.count_followers(actor.id)
          notes = Note.get_latest_notes(actor.id)

          render(
            conn,
            :show,
            actor: actor,
            following: following,
            followers: followers,
            notes: notes,
            layout: false
          )
        end
    end
  end
end